VirtualKeyboard
Opens the Virtual Keyboard of the System

Syntax:

- VirtualKeyboard.OPEN [ SHOW ]

- VirtualKeyboard.OPEN HIDE

Methods:

- VirtualKeyboard.Show

- VirtualKeyboard.Hide

- VirtualKeyboard.Release

Properties:

- VirtualKeyboard.IsRelease

- VirtualKeyboard.IsOpen

- VirtualKeyboard.IsVisible

- VirtualKeyboard.IsMinimize

- VirtualKeyboard.IsMaximize

- VirtualKeyboard.Handle

- VirtualKeyboard.Title [ := | --> ] cTitle

- VirtualKeyboard.Row [ := | --> ] nRow

- VirtualKeyboard.Col [ := | --> ] nCol

- VirtualKeyboard.Width [ := | --> ] nWidth

- VirtualKeyboard.Height [ := | --> ] nHeight

- VirtualKeyboard.FileName --> "OSK.EXE"

- VirtualKeyboard.FullFileName --> GetSystemDir()+"\OSK.EXE"

Example:

#include "hmg.ch"

FUNCTION Main

DEFINE WINDOW Form_1;

AT 0,0 ;

WIDTH 600 HEIGHT 600 ;

MAIN ;

TITLE "System Virtual Keyboard";

ON RELEASE IF (VirtualKeyboard.IsOpen == .T., VirtualKeyboard.RELEASE, NIL)

@ 50, 20 EDITBOX Editbox_1 WIDTH 550 HEIGHT 350 VALUE ""

@ 410, 280 BUTTON Button_1 CAPTION "On/Off" ACTION OnOff_VirtualKeyboard()

@ 450, 280 BUTTON Button_2 CAPTION "Release" ACTION IF (VirtualKeyboard.IsOpen == .T., VirtualKeyboard.RELEASE, NIL)

END WINDOW

CENTER WINDOW Form_1

ACTIVATE WINDOW Form_1

RETURN NIL

PROCEDURE OnOff_VirtualKeyboard

IF VirtualKeyboard.IsOpen == .F.

IF .NOT. FILE (VirtualKeyboard.FULLFILENAME)

RETURN

ENDIF

VirtualKeyboard.OPEN HIDE

Inkey (1) // Wait until the application is loaded

VirtualKeyboard.TITLE := "HMG Virtual Keyboard"

VirtualKeyboard.ROW := Form_1.ROW + Form_1.editbox_1.ROW + 50

VirtualKeyboard.COL := Form_1.COL + Form_1.editbox_1.COL + 20

VirtualKeyboard.SHOW

RETURN

ENDIF

IF VirtualKeyboard.IsVisible == .F.

VirtualKeyboard.SHOW

ELSE

VirtualKeyboard.HIDE

ENDIF

RETURN