HMG 3.0.36 (2011-05-31)

[danielmaximiliano]

Hi Rathinagiri:
Rathi phenomenal: rename my settings, copy a new hbmk.hbm within my application folder. included in the ide lib hbmzip.hbc because that gave me an error again.
although not included in my project.
The application compiles perfect!!

Thanks for your work.


Fenomenal RATHI: rename mis configuraciones, copie un nuevo
hbmk.hbm dentro de la carpeta de mi aplicacion. en el ide inclui
hbmzip.hbc ya que esa lib me dio de nuevo un error.
a pesar que no esta incluida dentro de mi proyecto.
la Aplicacion compila perfecto!!!!

Gracias por tu trabajo.

Saludos/Regards
DaNiElMaXiMiLiAnO

[Rathinagiri]

Kindly save this code as build.bat in c:\hmg folder. Now you can use IDE in the new version. For console mode, still I could not compile using IDE. However, it can be compiled using build.bat in command prompt with /cr switch.

Kindly test and tell me your opinion. If everything goes ok, we can remove 'test' in the name!

Code: Select all

@echo off

cls

rem ***************************************************************************
rem HMG 3.0 Build batch 
rem Roberto Lopez (2009.10.22)
rem ***************************************************************************

rem ***************************************************************************
rem Set variables
rem ***************************************************************************

set AppHmgVer=""
Set HmgPath=%~dp0

set /p HmgVer=<%HmgPath%\version.txt
echo %hmgver%

if exist hmgver.dat set /p AppHmgVer=<hmgver.dat

echo %AppHmgVer%


Set Path=%HmgPath%\util;%HmgPath%\mingw\bin;%HmgPath%\harbour\bin;

Set Resources=%HmgPath%\resources\hmg.o

set GT=-gtgui
set DEBUG=""
set BUILDTYPE=""
set REBUILDALL=""
set RUN=.T.
set MT=


rem ***************************************************************************
rem
rem Syntax:
rem
rem	Build [/i|/r|/d|/cs|/ci/cr] <PrgFile> | <filelist.hbp> [config.hbc]
rem	
rem	[/i] : incremental build
rem	[/r] : incremental build (rebuild all)
rem
rem	[/cs] : Console/mixed mode (std build)
rem	[/ci] : Console/mixed mode (incremental build)
rem	[/cr] : Console/mixed mode (incremental rebuild all)
rem
rem	[/d] : Debug mode (gui and console)
rem	
rem
rem	<filelist.hbm> : A text file with .hbp extension containing a source list
rem	<configfile.hbc>: A text file with configuration parameters as additional
rem	libs, include paths and lib paths.
rem 
rem		<configfile.hbc> Syntax:
rem 
rem		incpaths = incpath1 incpath2 ... incpathn
rem                   
rem		libpaths = libpath1 libpath2 ... libpathn
rem 
rem		libs = lib1 lib2 ... libn
rem
rem	- library names must not include 'lib' prefix nor '.a' extension.
rem
rem	- build.bat will create an 'error.log' file in the app folder when build
rem	process ends with an error condition.
rem
rem
rem ***************************************************************************

cls

echo building...

if exist hbmk.hbm del hbmk.hbm
if exist hbmk.log del hbmk.log
if exist windres.log del windres.log
if exist error.log del error.log
if exist _hmg_resconfig.h del _hmg_resconfig.h


rem ---------------------------------------------------------------------------
rem Parameters Processing
rem ---------------------------------------------------------------------------

rem ***************************************************************************
rem NO PARAMETERS OR HELP REQUESTED
rem ***************************************************************************

if "%1"=="" goto syntax
if "%1"=="/?" goto syntax
if "%1"=="-?" goto syntax
if "%1"=="/h" goto syntax
if "%1"=="/H" goto syntax
if "%1"=="-h" goto syntax
if "%1"=="-H" goto syntax
if "%1"=="-help" goto syntax
if "%1"=="-HELP" goto syntax

rem ***************************************************************************
rem No run after build
rem ***************************************************************************

if "%1"=="/n" goto norun
if "%1"=="/N" goto norun

:continue0

rem ***************************************************************************
rem Multi Thread
rem ***************************************************************************

if "%1"=="/mt" goto multithread
if "%1"=="/MT" goto multithread

:continue1

rem ***************************************************************************
rem Console Incremental Rebuild
rem ***************************************************************************

if "%1"=="/cr" goto consoleincrebuild
if "%1"=="/CR" goto consoleincrebuild

rem ***************************************************************************
rem Console Incremental
rem ***************************************************************************

if "%1"=="/ci" goto consoleincremental
if "%1"=="/CI" goto consoleincremental

rem ***************************************************************************
rem GUI Incremental Rebuild
rem ***************************************************************************

if "%1"=="/r" goto increbuild
if "%1"=="/R" goto increbuild

rem ***************************************************************************
rem Console Standard Build
rem ***************************************************************************

if "%1"=="/cs" goto console
if "%1"=="/CS" goto console

rem ***************************************************************************
rem If debug mode specified, use GTWIN and pass -b parameter
rem ***************************************************************************

if "%1"=="/d" goto debug
if "%1"=="/D" goto debug

rem ***************************************************************************
rem If /i parameter rceived set BUILDTYPE to incremental
rem ***************************************************************************

if "%1"=="/i" goto incremental
if "%1"=="/I" goto incremental

:continue

if exist %~n1.exe del %~n1.exe

if exist %~n1.exe goto error

rem ***************************************************************************
rem If a resource with the same base name as the first parameter exist compile it
rem ***************************************************************************

echo #define HMGRPATH %HmgPath%\RESOURCES > _hmg_resconfig.h
echo %HmgPath%\hmg.hbc > hbmk.hbm

if exist %~n1.rc copy /b %HmgPath%\resources\hmg.rc+%~n1.rc+%HmgPath%\resources\filler _temp.rc >NUL
if exist %~n1.rc redir -e windres.log windres -i _temp.rc -o _temp.o 
if exist %~n1.rc Set Resources=_temp.o

rem ***************************************************************************
rem invoke HBMK2
rem ***************************************************************************

IF NOT "%HMGVER%"=="%APPHMGVER%" IF EXIST .HBMK RMDIR /S /Q .hbmk

rem redir -eo  hbmk2 -o%~n1.exe %GT% %DEBUG% %MT% %BUILDTYPE% %REBUILDALL% -incpath=%HmgPath%\include -incpath=%CD% -L%HmgPath%\lib -lhmg -lhbmysql -lmysql -lcrypt -ledit -leditex -lgraph -lini -lreport -lhbwin -lhbziparc -lhbmzip -lmsvfw32 -lvfw32 -lsddodbc -lrddsql -lsddmy -lhbodbc -lodbc32 -lhbhpdf -lhbvpdf -lhbmemio -lhbsqlit3 -lsqlite3 -lhbfimage -lhbpgsql -lpq -lhbtip -lhbct -lhbmisc -lhbnetio -lxhb -prgflag=/q -cflag=-O3 %1 %2 %3 %4 %5 %6 %7 %8 %9 %Resources%  >hbmk.log
rem redir -eo  hbmk2 -o%~n1.exe %GT% %DEBUG% %MT% %BUILDTYPE% %REBUILDALL% -incpath=%HmgPath%\include -incpath=%CD% -L%HmgPath%\lib -lhmg -lhbmysql -lmysql -lcrypt -ledit -leditex -lgraph -lini -lreport -lhbwin -lhbziparc -lhbmzip -lmsvfw32 -lvfw32 -lsddodbc -lrddsql -lsddmy -lhbodbc -lodbc32 -lhbhpdf -lhbmemio -lhbsqlit3 -lsqlite3 -lhbfimage -lhbpgsql -lhbtip -lhbct -lhbmisc -lhbnetio -lxhb -prgflag=/q -cflag=-O3 %1 %2 %3 %4 %5 %6 %7 %8 %9 %Resources%  >hbmk.log
echo %HmgPath%\hmg.hbc > hbmk.hbm


redir -eo HBMK2 -o%~n1.exe %GT% %DEBUG% %MT% %BUILDTYPE% %REBUILDALL% %1 %2 %3 %4 %5 %6 %7 %8 -i%hmgpath%\include -lmsvfw32 -lvfw32 -lmysql >hbmk.log
goto end

rem ***************************************************************************
rem Procedure increbuild
rem ***************************************************************************

:increbuild

set BUILDTYPE=-inc
set REBUILDALL=-rebuild

shift

goto continue

rem ***************************************************************************
rem Procedure Console
rem ***************************************************************************

:console

shift

goto continueconsole

rem ***************************************************************************
rem Procedure Debug
rem ***************************************************************************

:debug

set GT=-gtwin
set DEBUG=-b

echo Options NoRunAtStartup > Init.cld

shift

goto continue

rem ***************************************************************************
rem Procedure Incremental
rem ***************************************************************************

:Incremental

set BUILDTYPE=-inc -head=native


shift
goto continue

rem ***************************************************************************
rem Procedure IncConsole
rem ***************************************************************************

:consoleincremental

set BUILDTYPE=-inc

shift

goto continueconsole

rem ***************************************************************************
rem Procedure IncConsole
rem ***************************************************************************

:consoleincrebuild

set BUILDTYPE=-inc
set REBUILDALL=-rebuild

shift

goto continueconsole

rem ***************************************************************************
rem Procedure ContinueConsole
rem ***************************************************************************


:continueconsole
rem echo %HmgPath%\hmgc.hbc > hbmk.hbm

IF NOT "%HMGVER%"=="%APPHMGVER%" IF EXIST .HBMK RMDIR /S /Q .hbmk

redir -eo HBMK2 -o%~n1.exe %DEBUG% %MT% %BUILDTYPE% %REBUILDALL% %1 %2 %3 %4 %5 %6 %7 %8 -std -i%hmgpath%\include -lmsvfw32 -lvfw32 >hbmk.log

goto end



rem ***************************************************************************
rem Procedure NoRun
rem ***************************************************************************

:norun

set RUN=.F.

shift

goto continue0

rem ***************************************************************************
rem Procedure Multithread
rem ***************************************************************************

:multithread

set MT=-mt

shift

goto continue1

rem ***************************************************************************
rem Procedure Error
rem ***************************************************************************

:error

echo Can't delete previous %~n1.exe version (still running?) > error.log

goto showlog

rem ***************************************************************************
rem Procedure Syntax
rem ***************************************************************************

:syntax

cls
echo :: Syntax:
echo ::
echo :: "Build [/i|/r|/d|/cs|/ci/cr] <PrgFile> | <filelist.hbp> [config.hbc]"
echo ::
echo :: [/i] : incremental build
echo :: [/r] : incremental build (rebuild all)
echo :: [/cs] : Console/mixed mode (std build)
echo :: [/ci] : Console/mixed mode (incremental build)
echo :: [/cr] : Console/mixed mode (incremental rebuild all)
echo :: [/d] : Debug mode (gui and console)
echo :: filelist.hbm : A text file with .hbp extension containing a source list
echo :: configfile.hbc: A text file with configuration parameters as additional
echo :: libs, include paths and lib paths.
echo ::
echo :: configfile.hbc Syntax:
echo ::
echo :: incpaths = incpath1 incpath2 ... incpathn
echo :: libpaths = libpath1 libpath2 ... libpathn
echo :: libs = lib1 lib2 ... libn
echo ::
echo :: library names must not include 'lib' prefix nor '.a' extension.
echo :: build.bat will create an 'error.log' file in the app folder when build
echo :: process ends with an error condition.
echo :: <.hbc> files in the current folder are automatically processed.
pause
goto stop

:end

rem ***************************************************************************
rem Cleanup
rem ***************************************************************************

rem If build error, create 'error.log' ----------------------------------------

if errorlevel 1 if exist windres.log copy /a windres.log+hbmk.log error.log >nul
if errorlevel 1 if not exist windres.log copy /a hbmk.log error.log >nul

rem If no build error, create 'build.log' ----------------------------------------

if errorlevel 0 if exist windres.log copy /a windres.log+hbmk.log build.log >nul
if errorlevel 0 if not exist windres.log copy /a hbmk.log build.log >nul


rem If no error strip the exe ---------------------------------------------------

if not errorlevel 1 if exist %~n1.exe strip.exe --strip-all %~n1.exe


rem If no error run the exe ---------------------------------------------------

if "%RUN%"==".T." if not errorlevel 1 if exist %~n1.exe %~n1.exe

rem Delete temporary files ----------------------------------------------------

if exist windres.log del windres.log
if exist hbmk.hbm del hbmk.hbm
if exist hbmk.log del hbmk.log
if exist _hmg_resconfig.h del _hmg_resconfig.h

if exist _temp.rc del _temp.rc

if exist _temp.o  del _temp.o

rem Create Version Sign -------------------------------------------------------

echo %hmgver%> hmgver.dat

:showlog

if exist error.log type error.log
if exist build.log type build.log

:stop

[Mario Mansilla]

Hola Rathi :
Perfecto tambien mis aplicaciones ya compilan bien como en HMG.035 .
Ahora bien hay una de ellas en la cual uso la funcion DbZap() con la cual me da error en HMG.036 y no me crea el ejecutable . Cuando la misma aplicacion la compilo con HMG.035 lo hace sin problemas .
¿Que funcion tengo que agregar ?
Saludos .
Mario Mansilla

Hi Rathi:
Perfect also compile my applications and well as in HMG.035.
But there is one in which I use DbZap function () which gives me the error in HMG.036 and I created the executable. When the same application compiled with the HMG.035 do it without problems.
What features do I have to add?
Greetings.
Mario Mansilla

[danielmaximiliano]

Hola Mario: probaste mirar en

http://www.harbour-project.org/doc/__dbzap.htm

DaNiElMaXiMiLiAnO

[Mario Mansilla]

Hola Daniel :
Muchas gracias por contestar . Probe con Alias->(__Dbzap()) y funciona perfecto . Habran hecho cambios en los nombres en Harbour desde la version que venia con HMG.035 con respecto a la nueva HMG.036
Saludos.
Mario Mansilla

[danielmaximiliano]

Recuerda que la Tabla/Base debe estar abierta en MODO EXCLUSIVO cuando TRABAJES en RED