HMGforum.com

Code: Select all

#include <hmg.ch>
#include "hfcl.ch"

Function Main
   define window barcode at 0, 0 width 400 height 100 title "Barcode PDF Sample" main
      define label l1
         row 10
         col 10
         width 100
         value 'Enter Barcode'
      end label
      define textbox t1
         row 10
         col 110
         width 100
      end textbox
      define button b1
         row 10
         col 220
         caption 'Create PDF'
         action createpdf()
      end button
   end window
   barcode.center
   barcode.activate
Return

function createpdf
   local cImage := 'barcode.png'
   local nReturn := 0
   local lSuccess := .f.
   nReturn := HMG_CreateBarCode( barcode.t1.value,;
                             "PDF417",;
                             2,;
                             100,;
                             .f.,;
                             cImage )
   if nReturn == 0
      msgstop( 'Barcode Creation error!' )
      return nil
   endif
   if file( 'barcode.png' )
      SELECT HPDFDOC 'HMG_barcode.pdf' TO lSuccess papersize HPDF_PAPER_A4
      if lSuccess
         START HPDFDOC
            START HPDFPAGE
               @ 10,  10 HPDFPRINT IMAGE "barcode.png" WIDTH 172 HEIGHT 78
            END HPDFPAGE   
         END HPDFDOC
      endif
   endif
   return nil