Reporte error Hmg 3.0 VI - HmgIde 3.0 - Patch 3.0

[Mario Mansilla]

Hola :
Tengo implemetado un sistema con hmg 2.95 + HmgIde 2.94 .
Cuando actualizo a Hmg 3.0 + HmgIde 3.0 me da el siguiente error con la funcion TFileRead de Harbour

Saludos .
Mario Mansilla

Hi:
I have a system with implemetado hmg HmgIde 2.94 + 2.95.
When I upgrade to 3.0 + HmgIde Hmg 3.0 I get this error with the function TFileRead Harbor

Greetings.
Mario Mansilla

hbmk2: Compiling Harbour sources...
Harbour 2.0.0beta3 (Rev. 12700)
Copyright (c) 1999-2009, http://www.harbour-project.org/
hbmk2: Compiling...
hbmk2: Linking... Main.exe
.hbmk\win\mingw\recepcion.o:recepcion.c:(.data+0x1b8): undefined reference to `HB_FUN_TFILEREAD'
collect2: ld returned 1 exit status
hbmk2: Error: Running linker. 1
gcc.exe .hbmk\win\mingw\main.o .hbmk\win\mingw\articulo.o .hbmk\win\mingw\depurar.o .hbmk\win\mingw\impresion.o .hbmk\win\mingw\impuesto.o .hbmk\win\mingw\infohd.o .hbmk\win\mingw\licencia.o .hbmk\win\mingw\ligados.o .hbmk\win\mingw\recepcion.o .hbmk\win\mingw\reportes.o .hbmk\win\mingw\rubros.o .hbmk\win\mingw\setup.o .hbmk\win\mingw\tasas.o .hbmk\win\mingw\transmision.o .hbmk\win\mingw\_hbmkaut.o _temp.o -mwindows -Wl,--start-group -lminigui -lhbmysql -lmysql -lcrypt -ledit -leditex -lgraph -lini -lreport -lhbwin -lhbziparc -lhbmzip -lmsvfw32 -lvfw32 -lsddodbc -lrddsql -lsddmy -lhbodbc -lodbc32 -lhbhpdf -lhbvpdf -lhbmemio -lhbsqlit3 -lsqlite3 -lhbfimage -lhbpgsql -lpq -lhbtip -lhbct -lhbextern -lhbdebug -lhbvm -lhbrtl -lhblang -lhbcpage -lgtcgi -lgtpca -lgtstd -lgtwin -lgtwvt -lgtgui -lhbrdd -lhbuddall -lhbusrrdd -lrddntx -lrddcdx -lrddnsx -lrddfpt -lhbrdd -lhbhsx -lhbsix -lhbmacro -lhbcplr -lhbpp -lhbcommon -lkernel32 -luser32 -lgdi32 -ladvapi32 -lws2_32 -lwinspool -lcomctl32 -lcomdlg32 -lshell32 -luuid -lole32 -loleaut32 -lmpr -lwinmm -lmapi32 -limm32 -lmsimg32 -lwininet -lhbpcre -lhbzlib -Wl,--end-group -oMain.exe -Lc:/hmg/harbour/lib -Lc:/hmg/lib

[esgici]

Hi

Regarding a very old Harbour doc, TFileRead is in libmisc library.

Regards

--

Esgici

[esgici]

Hi

And in current release of Harbour we have libhbmisc.a in \lib\win\mingw DIR.

Regards

--

Esgici

[Mario Mansilla]

Hola Esgici :
En el compile de la version 2.95 tengo varias referencias a la lhbmisc pero en el build de la nueva version no tengo ninguna referencia .
En el harbour de la version 2.94 tengo la libhbmisc.a en \Harbour\lib , al igual que en la version 3.0 .
Saludos .
Mario Mansilla

Hello Esgici:
In compile the 2.95 version have several references to lhbmisc but in the build of the new version does not have any reference.
In the harbour of the 2.94 version have libhbmisc.a in \Harbour\lib , as in the version 3.0.

Greetings.
Mario Mansilla

[Roberto Lopez]

Hola :
Tengo implemetado un sistema con hmg 2.95 + HmgIde 2.94 .
Cuando actualizo a Hmg 3.0 + HmgIde 3.0 me da el siguiente error con la funcion TFileRead de Harbour

Saludos .
Mario Mansilla

Hi:
I have a system with implemetado hmg HmgIde 2.94 + 2.95.
When I upgrade to 3.0 + HmgIde Hmg 3.0 I get this error with the function TFileRead Harbor

Greetings.
Mario Mansilla

hbmk2: Compiling Harbour sources...
Harbour 2.0.0beta3 (Rev. 12700)
Copyright (c) 1999-2009, http://www.harbour-project.org/
hbmk2: Compiling...
hbmk2: Linking... Main.exe
.hbmk\win\mingw\recepcion.o:recepcion.c:(.data+0x1b8): undefined reference to `HB_FUN_TFILEREAD'
collect2: ld returned 1 exit status
hbmk2: Error: Running linker. 1
gcc.exe .hbmk\win\mingw\main.o .hbmk\win\mingw\articulo.o .hbmk\win\mingw\depurar.o .hbmk\win\mingw\impresion.o .hbmk\win\mingw\impuesto.o .hbmk\win\mingw\infohd.o .hbmk\win\mingw\licencia.o .hbmk\win\mingw\ligados.o .hbmk\win\mingw\recepcion.o .hbmk\win\mingw\reportes.o .hbmk\win\mingw\rubros.o .hbmk\win\mingw\setup.o .hbmk\win\mingw\tasas.o .hbmk\win\mingw\transmision.o .hbmk\win\mingw\_hbmkaut.o _temp.o -mwindows -Wl,--start-group -lminigui -lhbmysql -lmysql -lcrypt -ledit -leditex -lgraph -lini -lreport -lhbwin -lhbziparc -lhbmzip -lmsvfw32 -lvfw32 -lsddodbc -lrddsql -lsddmy -lhbodbc -lodbc32 -lhbhpdf -lhbvpdf -lhbmemio -lhbsqlit3 -lsqlite3 -lhbfimage -lhbpgsql -lpq -lhbtip -lhbct -lhbextern -lhbdebug -lhbvm -lhbrtl -lhblang -lhbcpage -lgtcgi -lgtpca -lgtstd -lgtwin -lgtwvt -lgtgui -lhbrdd -lhbuddall -lhbusrrdd -lrddntx -lrddcdx -lrddnsx -lrddfpt -lhbrdd -lhbhsx -lhbsix -lhbmacro -lhbcplr -lhbpp -lhbcommon -lkernel32 -luser32 -lgdi32 -ladvapi32 -lws2_32 -lwinspool -lcomctl32 -lcomdlg32 -lshell32 -luuid -lole32 -loleaut32 -lmpr -lwinmm -lmapi32 -limm32 -lmsimg32 -lwininet -lhbpcre -lhbzlib -Wl,--end-group -oMain.exe -Lc:/hmg/harbour/lib -Lc:/hmg/lib

Please, replace 'build.bat' with the following:

Code: Select all

@echo off

rem ***************************************************************************
rem HMG 3.0 Build batch 
rem Roberto Lopez (2009.10.16)
rem Syntax:
rem
rem	Build [/i|/r|/d|/cs|/ci/cr] <PrgFile> | <filelist.hbp> [config.hbc]
rem	
rem	[/i] : incremental build
rem	[/r] : incremental build (rebuild all)
rem
rem	[/cs] : Console/mixed mode (std build)
rem	[/ci] : Console/mixed mode (incremental build)
rem	[/cr] : Console/mixed mode (incremental rebuild all)
rem
rem	[/d] : Debug mode (gui and console)
rem	
rem
rem	<filelist.hbm> : A text file with .hbp extension containing a source list
rem	<configfile.hbc>: A text file with configuration parameters as additional
rem	libs, include paths and lib paths.
rem 
rem		<configfile.hbc> Syntax:
rem 
rem		incpaths = incpath1 incpath2 ... incpathn
rem                   
rem		libpaths = libpath1 libpath2 ... libpathn
rem 
rem		libs = lib1 lib2 ... libn
rem
rem	- library names must not include 'lib' prefix nor '.a' extension.
rem
rem	- build.bat will create an 'error.log' file in the app folder when build
rem	process ends with an error condition.
rem
rem
rem ***************************************************************************

cls

echo building...

if exist hbmk.log del hbmk.log
if exist hbmk.so.log del hbmk.so.log
if exist windres.log del windres.log
if exist error.log del error.log

rem ***************************************************************************
rem Set variables
rem ***************************************************************************

Set Path=c:\hmg\util;c:\hmg\mingw\bin;c:\hmg\harbour\bin;%PATH%
if "%Resources%"==""  Set Resources=c:\hmg\resources\minigui.o
if "%HmgPath%" =="" Set HmgPath=c:\hmg

set GT=-gtgui
set DEBUG=""
set BUILDTYPE=""
set REBUILDALL=""
set RUN=.T.

rem ---------------------------------------------------------------------------
rem Parameters Processing
rem ---------------------------------------------------------------------------

rem ***************************************************************************
rem No run after build
rem ***************************************************************************

if "%1"=="/n" goto norun
if "%1"=="/N" goto norun

:continue0

rem ***************************************************************************
rem Console Incremental Rebuild
rem ***************************************************************************

if "%1"=="/cr" goto consoleincrebuild
if "%1"=="/CR" goto consoleincrebuild

rem ***************************************************************************
rem Console Incremental
rem ***************************************************************************

if "%1"=="/ci" goto consoleincremental
if "%1"=="/CI" goto consoleincremental

rem ***************************************************************************
rem GUI Incremental Rebuild
rem ***************************************************************************

if "%1"=="/r" goto increbuild
if "%1"=="/R" goto increbuild

rem ***************************************************************************
rem Console Standard Build
rem ***************************************************************************

if "%1"=="/cs" goto console
if "%1"=="/CS" goto console

rem ***************************************************************************
rem If debug mode specified, use GTWIN and pass -b parameter
rem ***************************************************************************

if "%1"=="/d" goto debug
if "%1"=="/D" goto debug

rem ***************************************************************************
rem If /i parameter rceived set BUILDTYPE to incremental
rem ***************************************************************************

if "%1"=="/i" goto incremental
if "%1"=="/I" goto incremental

rem ***************************************************************************
rem If /i parameter rceived set BUILDTYPE to incremental
rem ***************************************************************************

if "%1"=="/i" goto incremental
if "%1"=="/I" goto incremental

:continue

if exist %~n1.exe del %~n1.exe

if exist %~n1.exe goto error

rem ***************************************************************************
rem If a resource with the same base name as the first parameter exist compile it
rem ***************************************************************************

if exist %~n1.rc copy /b %HmgPath%\resources\minigui.rc+%~n1.rc+%HmgPath%\resources\filler _temp.rc >NUL
if exist %~n1.rc redir -e windres.log windres -i _temp.rc -o _temp.o 
if exist %~n1.rc Set Resources=_temp.o

rem ***************************************************************************
rem invoke HBMK2
rem ***************************************************************************

redir -eo  hbmk2 -nohbc -o%~n1.exe %GT% %DEBUG% -head=real %BUILDTYPE% %REBUILDALL% -incpath=%HmgPath%\include -incpath=%CD% -L%HmgPath%\lib -lminigui -lhbmysql -lmysql -lcrypt -ledit -leditex -lgraph -lini -lreport -lhbwin -lhbziparc -lhbmzip -lmsvfw32 -lvfw32 -lsddodbc -lrddsql -lsddmy -lhbodbc -lodbc32 -lhbhpdf -lhbvpdf -lhbmemio -lhbsqlit3 -lsqlite3 -lhbfimage.a -lhbpgsql -lpq -lhbtip -lhbct -lhbmisc -prgflag=/q %1 %2 %3 %4 %5 %6 %7 %8 %9 %Resources%  >hbmk.log

goto end

rem ***************************************************************************
rem Procedure increbuild
rem ***************************************************************************

:increbuild

set BUILDTYPE=-inc
set REBUILDALL=-rebuild

shift

goto continue

rem ***************************************************************************
rem Procedure Console
rem ***************************************************************************

:console

set GT=-gtwin

shift

goto continue

rem ***************************************************************************
rem Procedure Debug
rem ***************************************************************************

:debug

set GT=-gtwin
set DEBUG=-b

echo Options NoRunAtStartup > Init.cld

shift

goto continue

rem ***************************************************************************
rem Procedure Incremental
rem ***************************************************************************

:Incremental

set BUILDTYPE=-inc

shift
goto continue

rem ***************************************************************************
rem Procedure IncConsole
rem ***************************************************************************

:consoleincremental

set BUILDTYPE=-inc
set GT=-gtwin

shift

goto continue

rem ***************************************************************************
rem Procedure IncConsole
rem ***************************************************************************

:consoleincrebuild

set BUILDTYPE=-inc
set GT=-gtwin
set REBUILDALL=-rebuild

shift

goto continue

rem ***************************************************************************
rem Procedure NoRun
rem ***************************************************************************

:norun

set RUN=.F.

shift

goto continue0

rem ***************************************************************************
rem Procedure Error
rem ***************************************************************************

:error

echo Can't delete previous %~n1.exe version (still running?) > error.log

goto showlog

:end

rem ***************************************************************************
rem Cleanup
rem ***************************************************************************

rem If build error, create 'error.log' ----------------------------------------

if errorlevel 1 if exist windres.log copy /b windres.log+hbmk.log error.log >nul

if errorlevel 1 if not exist windres.log copy /b hbmk.log error.log >nul

rem If no error run the exe ---------------------------------------------------

if "%RUN%"==".T." if not errorlevel 1 if exist %~n1.exe %~n1.exe

rem Delete temporary files ----------------------------------------------------

if exist windres.log del windres.log
if exist hbmk.log del hbmk.log
if exist hbmk.so.log del hbmk.so.log

if exist _temp.rc del _temp.rc

if exist _temp.o  del _temp.o

rem if exist delete debugger file ---------------------------------------------

if exist init.cld del init.cld

:showlog

if exist error.log type error.log

Thanks for reporting.

Regards,

Roberto.

[Mario Mansilla]

Muchas Gracias Roberto , ahora funciona bien .
Saludos .
Mario Mansilla

Thank you very much Robert, now works fine.
Greetings.
Mario Mansilla