HMGforum.com

Posted: **Fri Jul 29, 2011 2:08 am**

Hi Friends, how to convert characters to uppercase in textbox?

Posted: **Sun Jul 31, 2011 11:19 am**

Friends, to decide the problem with CaseConvert and MaxLength, I modified the file textbox.prg:

// Internal Data

   DATA nMaxLength                                INIT   0

Code: Select all

METHOD MaxLength( nValue ) CLASS TEXTBOX

   IF PCOUNT() == 0
      RETURN ::nValue
   ELSEIF PCOUNT() == 1
      ::nMaxLength := nValue
   ENDIF

   RETURN NIL

Code: Select all

METHOD CASEConvert( nValue ) CLASS TEXTBOX

   IF PCOUNT() == 0
      RETURN ::nValue
   ELSEIF PCOUNT() == 1
      ::nCaseConvert := nValue
   ENDIF

   RETURN NIL

Code: Select all

METHOD ProcessTextChange( cText ) CLASS TEXTBOX
   LOCAL icp, InBufferLeft, InBufferRight

   HB_SYMBOL_UNUSED( cText )

   IF ::lDateTextBoxActive
      ::lDateTextBoxActive := .F.
   ELSE
      icp := ::oQTObject:cursorPosition()
      IF ::nCaseConvert>0
       cText := IF(::nCaseConvert==1,UPPER(cText),LOWER(cText))
       ::oQTObject:setText( cText )
       ::oQTObject:setCursorPosition( icp )
      ENDIF
      IF ::nMaxLength>0
         IF Len( cText ) > ::nMaxLength
            InBufferLeft := Left( cText , icp )
            InBufferRight := Right( cText , Len( cText ) - icp - 1 )
            ::oQTObject:setText( LEFT(InBufferLeft + InBufferRight,::nMaxLength) )
            ::oQTObject:setCursorPosition( icp )
         ENDIF
      ENDIF
      IF Len( ::cInputMask ) > 0
         IF ::cTextBoxType == 'MASKEDTEXT'
            IF ::lMaskedFlag == .T.
               Self:ProcessCharmask( .t. )
             ENDIF
            IF ValType( ::bOnChange ) != 'U'
               Eval( ::bOnChange )
            ENDIF
         ELSEIF ::cTextBoxType == 'CHARMASKTEXT'
            Self:ProcessCharMask()
            IF ValType( ::bOnChange ) != 'U'
               Eval( ::bOnChange )
            ENDIF
         ENDIF

      ELSE

         IF ::cTextBoxType == 'NUMTEXT'
            Self:ProcessNumText()
         ENDIF
         IF ValType( ::bOnChange ) != 'U'
            Eval( ::bOnChange )
         ENDIF
      ENDIF

   ENDIF

RETURN NIL

I do not know if it is the best solution, but it gave certain!

Samples:

Code: Select all

      With Object oFriend := TextBox():New( "oFriend" )
         :Row            := 85
         :Col            := 15
         :Width          := 485
         :Height         := 20
         :ToolTip        := 'Name of the Friend'
         :MaxLength      := 50
         :OnEnter        := { || InsertTab() }
         :CaseConvert    := 1
      End With

Posted: **Sun Jul 31, 2011 12:42 pm**

It gives error with accented letters (ÁÉÃÕÇ)

Posted: **Mon Aug 01, 2011 12:14 pm**

Hi Friends, problem resolved:

Code: Select all

METHOD ProcessTextChange( cText ) CLASS TEXTBOX
   LOCAL icp, InBufferLeft, InBufferRight, InBuffer

   HB_SYMBOL_UNUSED( cText )

   IF ::lDateTextBoxActive
      ::lDateTextBoxActive := .F.
   ELSE
      icp := ::oQTObject:cursorPosition()
      IF ::nCaseConvert>0
       InBuffer := ::oQTObject:text()
       InBuffer := IF(::nCaseConvert==1,UPPER(InBuffer),LOWER(InBuffer))
       ::oQTObject:setText( InBuffer )
       ::oQTObject:setCursorPosition( icp )
      ENDIF
      IF ::nMaxLength>0
         InBuffer := ::oQTObject:text()
         IF Len( InBuffer ) > ::nMaxLength
            InBufferLeft := Left( InBuffer , icp )
            InBufferRight := Right( InBuffer , Len( InBuffer ) - icp - 1 )
            ::oQTObject:setText( LEFT(InBufferLeft + InBufferRight,::nMaxLength) )
            ::oQTObject:setCursorPosition( icp )
         ENDIF
      ENDIF
      IF Len( ::cInputMask ) > 0
         IF ::cTextBoxType == 'MASKEDTEXT'
            IF ::lMaskedFlag == .T.
               Self:ProcessCharmask( .t. )
             ENDIF
            IF ValType( ::bOnChange ) != 'U'
               Eval( ::bOnChange )
            ENDIF
         ELSEIF ::cTextBoxType == 'CHARMASKTEXT'
            Self:ProcessCharMask()
            IF ValType( ::bOnChange ) != 'U'
               Eval( ::bOnChange )
            ENDIF
         ENDIF

      ELSE

         IF ::cTextBoxType == 'NUMTEXT'
            Self:ProcessNumText()
         ENDIF
         IF ValType( ::bOnChange ) != 'U'
            Eval( ::bOnChange )
         ENDIF
      ENDIF

   ENDIF

RETURN NIL

Posted: **Mon Aug 01, 2011 1:16 pm**

Nice work

Posted: **Tue Aug 02, 2011 8:00 am**

Code: Select all

METHOD MaxLength( nValue ) CLASS TEXTBOX

   IF PCOUNT() == 0
      RETURN ::nValue
   ELSEIF PCOUNT() == 1
      ::nMaxLength := nValue
   ENDIF

   RETURN NIL

Code: Select all

METHOD CASEConvert( nValue ) CLASS TEXTBOX

   IF PCOUNT() == 0
      RETURN ::nValue
   ELSEIF PCOUNT() == 1
      ::nCaseConvert := nValue
   ENDIF

   RETURN NIL

Sorry, but this code has an error in the RETURN ::nValue...

Posted: **Tue Aug 02, 2011 11:22 am**

Correct, it is true:

Code: Select all

METHOD CASEConvert( nValue ) CLASS TEXTBOX

   IF PCOUNT() == 0
      RETURN ::nCaseConvert
   ELSEIF PCOUNT() == 1
      ::nCaseConvert := nValue
   ENDIF

   RETURN NIL

Code: Select all

METHOD MaxLength( nValue ) CLASS TEXTBOX

   IF PCOUNT() == 0
      RETURN ::nMaxLength
   ELSEIF PCOUNT() == 1
      ::nMaxLength := nValue
   ENDIF

   RETURN NIL

Sorry!

Posted: **Wed Aug 03, 2011 9:36 am**

Patch commited to svn

please check

Posted: **Wed Aug 03, 2011 11:15 am**

mrduck, need only change:

Code: Select all

   DATA nMaxLength                                INIT   0

Thanks!

Posted: **Wed Aug 03, 2011 1:01 pm**

pctoledo wrote:mrduck, need only change:
Code: Select all
   DATA nMaxLength                                INIT   0
Thanks!

done, sorry

HMGforum.com

Uppercase in textbox (HMG4)

Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)

Re: Uppercase in textbox (HMG4)