HMGforum.com

Code: Select all

// Move the mouse cursor within Grid control and observe StatusBar.

#include 'hmg.ch'

FUNCTION Main()

  OpenData()

  DEFINE WINDOW Main_WA;
    MAIN;
    WIDTH  310;
    HEIGHT 235;
    TITLE  'Grid Test'

    DEFINE GRID Users_GR
      ROW             10
      COL             10
      WIDTH          280
      HEIGHT         120
      HEADERS        {'Record', 'Name', 'Price'}
      WIDTHS         {55, 130, 70}
      CELLNAVIGATION .F.
      ROWSOURCE      'Comp'
      COLUMNFIELDS   {'RecNo()', 'Name', 'Price'}
      JUSTIFY        {GRID_JTFY_RIGHT, GRID_JTFY_LEFT, GRID_JTFY_RIGHT}
    END GRID

    DEFINE BUTTON Exit_BU
      ROW      140
      COL      100
      WIDTH     80
      HEIGHT    25
      CAPTION 'Exit'
      ACTION   Main_WA.RELEASE
    END BUTTON
  
    DEFINE STATUSBAR
      STATUSITEM ''
      STATUSITEM '' WIDTH 200
    END STATUSBAR

    DEFINE TIMER Timer;
      INTERVAL 10;
      ACTION   UpdateStatus()

    ON KEY ESCAPE ACTION Main_WA.RELEASE

  END WINDOW

  Main_WA.Users_GR.RECNO := 1

  Main_WA.CENTER
  Main_WA.ACTIVATE

RETURN NIL

FUNCTION UpdateStatus()

  Main_WA.STATUSBAR.Item(1) := 'RecNo(): ' + LTrim(Str(RecNo()))
  Main_WA.STATUSBAR.Item(2) := 'Grid.RECNO: ' + LTrim(Str(Main_WA.Users_GR.RECNO))

RETURN NIL

FUNCTION OpenData()

  IF File('Comp.dbf')
    dbUseArea(NIL, NIL, 'Comp')
  ELSE
    dbCreate('Comp', {{'Name', 'C', 30, 0}, {'Price', 'N', 6, 2}})
    dbUseArea(NIL, NIL, 'Comp')

    dbAppend()
    Comp->Name  := 'Main board'
    Comp->Price := 120.34
    dbAppend()
    Comp->Name  := 'Processor'
    Comp->Price := 97.95
    dbAppend()
    Comp->Name  := 'RAM'
    Comp->Price := 204.58
    dbAppend()
    Comp->Name  := 'HDD'
    Comp->Price := 142.71
    dbAppend()
    Comp->Name  := 'SSD'
    Comp->Price := 316.94
    dbAppend()
    Comp->Name  := 'Graphics card'
    Comp->Price := 143.48
    dbAppend()
    Comp->Name  := 'Power supply'
    Comp->Price := 54.29
    dbAppend()
    Comp->Name  := 'PC case'
    Comp->Price := 72.85
  ENDIF

RETURN NIL